Нужна помощь по макросам

'Источник : http://support.microsoft.com/kb/213449

Function Convert_Decimal(Degree_Deg As String) As Double
   ' Declare the variables to be double precision floating-point.
   Dim degrees As Double
   Dim minutes As Double
   Dim seconds As Double
   ' Set degree to value before "°" of Argument Passed.
   Degree_Deg = Application.Substitute(Degree_Deg, ",", ".") 'XL97
   'Degree_Deg = Replace(Degree_Deg, ",", ".")               'XL2000
   degrees = Val(Left(Degree_Deg, InStr(1, Degree_Deg, "°") - 1))
   ' Set minutes to the value between the "°" and the "'"
   ' of the text string for the variable Degree_Deg divided by
   ' 60. The Val function converts the text string to a number.
   minutes = Val(Mid(Degree_Deg, InStr(1, Degree_Deg, "°") + 2, _
             InStr(1, Degree_Deg, "'") - InStr(1, Degree_Deg, _
             "°") - 2)) / 60
    ' Set seconds to the number to the right of "'" that is
    ' converted to a value and then divided by 3600.
   seconds = Val(Mid(Degree_Deg, InStr(1, Degree_Deg, "'") + _
            2, Len(Degree_Deg) - InStr(1, Degree_Deg, "'") - 2)) / 3600
   Convert_Decimal = degrees + minutes + seconds
End Function

Function Convert_Degree(Decimal_Deg) As Variant
    'Set degree to Integer of Argument Passed
    degrees = Int(Decimal_Deg)
    'Set minutes to 60 times the number to the right
    'of the decimal for the variable Decimal_Deg
    minutes = (Decimal_Deg - degrees) * 60
    'Set seconds to 60 times the number to the right of the
    'decimal for the variable Minute
    seconds = Application.Round(((minutes - Int(minutes)) * 60), 7)
    'Returns the Result of degree conversion
    '(for example, 10.46 = 10~ 27  ' 36")
     Convert_Degree = " " & degrees & "° " & Int(minutes) & "' " _
          & seconds & Chr(34)
End Function