Помогите пожалуйста решить задачу. Delphi

unit MainUnit;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ThrUnit;

type
  TMainForm = class(TForm)
    EditSl1: TEdit;
    EditSl2: TEdit;
    EditSum: TEdit;
    BtnSum: TButton;
    lNow: TLabel;
    procedure BtnSumClick(Sender: TObject);
    procedure EditSl1KeyPress(Sender: TObject; var Key: Char);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure lNowDblClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  MainForm: TMainForm;
  lTimeThr: TimeThread;

implementation

{$R *.dfm}

procedure TMainForm.BtnSumClick(Sender: TObject);
begin
  EditSum.Text := FloatToStr(StrToFloat(EditSl1.Text) + StrToFloat(EditSl2.Text)
    );
end;

procedure TMainForm.EditSl1KeyPress(Sender: TObject; var Key: Char);
begin
  with (Sender as TEdit) do
  begin
    if (CharInSet(Key, ['/', '.', ','])) or (Key = 'б') or (Key = 'Б') or
      (Key = 'ю') or (Key = 'Ю') then
      Key := DecimalSeparator
    else if Key <> #8 then
      if not CharInSet(Key, ['0' .. '9']) then
        Key := #0;
    if ((Key = ',') and ((Pos(',', Text) <> 0) or (Text = ''))) then
      Key := #0;
  end;
end;

procedure TMainForm.FormCreate(Sender: TObject);
begin
  lTimeThr := TimeThread.Create(tpLower, Self.lNow);
end;

procedure TMainForm.FormDestroy(Sender: TObject);
begin
  if Assigned(lTimeThr) then
  begin
    SetEvent(lTimeThr.TermEvent);
    lTimeThr := nil;
  end;
end;

procedure TMainForm.lNowDblClick(Sender: TObject);
begin
  if Assigned(lTimeThr) then
  begin
    SetEvent(lTimeThr.TermEvent);
    lTimeThr := nil;
  end
  else
    lTimeThr := TimeThread.Create(tpLower, Self.lNow);
end;

end.

unit ThrUnit;

interface

uses
  Classes, SysUtils, Windows, StdCtrls;

type
  TimeThread = class(TThread)
  private
    { Private declarations }
    FTermEvent: THandle;
    LN: TLabel;
  public
    constructor Create(ThreadPriority: TThreadPriority; labelNow: TLabel);
    property TermEvent: THandle read FTermEvent;
  protected
    procedure Execute; override;
  end;

implementation

{ TimeThread }

constructor TimeThread.Create(ThreadPriority: TThreadPriority;
  labelNow: TLabel);
begin
  inherited Create(True); // Поток создаем в состоянии «Приостановлен»
  FreeOnTerminate := True; // Поток освободит ресурсы при окончании работы
  LN := labelNow;

  { хэндл события завершения потока }
  FTermEvent := CreateEvent(nil, True, False, nil);

  Self.Priority := ThreadPriority; // приоритет потока из .. см ниже
  // tpIdle, tpLowest, tpLower, tpNormal, tpHigher, tpHighest, tpTimeCritical
  Resume; // Переводим поток в состояние «Активен»
end;

procedure TimeThread.Execute;
var
  hDir: THandle;
  WaitHandles: array [0 .. 1] of THandle;
begin
  try
    while True do
    begin
      // обновляем время
      Synchronize( procedure begin try LN.Caption := FormatDateTime
          (' h:nn:ss  dd mmm yyyy', now); except end; end);
      { ожидаем событие 500мс - можно указать любое число}
      if WaitForSingleObject(FTermEvent, 500) = WAIT_OBJECT_0 then
        Break;
    end;
  finally

  end;

end;

end.

program Zadacha1;

uses
  Forms,
  MainUnit in 'MainUnit.pas' {MainForm},
  ThrUnit in 'ThrUnit.pas';

{$R *.res}

begin
  Application.Initialize;
  Application.MainFormOnTaskbar := True;
  Application.CreateForm(TMainForm, MainForm);
  Application.Run;
end.

object MainForm: TMainForm
  Left = 0
  Top = 0
  BorderIcons = [biSystemMenu, biMinimize]
  BorderStyle = bsSingle
  Caption = #1057#1091#1084#1084#1072' +  '#1087#1086#1090#1086#1082
  ClientHeight = 170
  ClientWidth = 327
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'Tahoma'
  Font.Style = []
  OldCreateOrder = False
  Position = poDesktopCenter
  OnCreate = FormCreate
  OnDestroy = FormDestroy
  PixelsPerInch = 96
  TextHeight = 13
  object lNow: TLabel
    Left = 51
    Top = 120
    Width = 206
    Height = 25
    AutoSize = False
    Font.Charset = RUSSIAN_CHARSET
    Font.Color = clBlue
    Font.Height = -13
    Font.Name = 'Times New Roman'
    Font.Style = []
    ParentFont = False
    OnDblClick = lNowDblClick
  end
  object EditSl1: TEdit
    Left = 8
    Top = 8
    Width = 121
    Height = 21
    Alignment = taRightJustify
    TabOrder = 0
    Text = '100'
    OnKeyPress = EditSl1KeyPress
  end
  object EditSl2: TEdit
    Left = 8
    Top = 35
    Width = 121
    Height = 21
    Alignment = taRightJustify
    TabOrder = 1
    Text = '200'
    OnKeyPress = EditSl1KeyPress
  end
  object EditSum: TEdit
    Left = 183
    Top = 21
    Width = 121
    Height = 21
    Alignment = taCenter
    Enabled = False
    TabOrder = 2
  end
  object BtnSum: TButton
    Left = 112
    Top = 62
    Width = 97
    Height = 35
    Caption = #1057#1091#1084#1084#1072
    TabOrder = 3
    OnClick = BtnSumClick
  end
end