Проблема с хуком

library ChHook;

uses
  Windows,
  Messages,
  SysUtils,
  UChConsts in '..\Server\UChConsts.pas',
  UChLog in 'Misc\UChLog.pas';

var
  MMFHandle: THandle;
  WMMyPost: Cardinal;


function CbtFunc(
  Code: Integer; WParam: WPARAM; LParam: LPARAM): LongInt; stdcall;
begin
  if Code < 0 then begin
    Result := CallNextHookEx(GlobalData^.SysHook, Code, WParam, LParam);
    Exit;
  end;

  case Code of
    HCBT_KEYSKIPPED:
      PostMessage(GlobalData^.AppWnd, WMMyPost, 2, 0);

    HCBT_CLICKSKIPPED:
      if
        (WParam = WM_LBUTTONDOWN) or (WParam = WM_RBUTTONDOWN) or
        (WParam = WM_MBUTTONUP)
      then
        PostMessage(GlobalData^.AppWnd, WMMyPost, 3, 0)
      else if WParam = WM_MOUSEWHEEL then
        PostMessage(GlobalData^.AppWnd, WMMyPost, 6, 0);

    HCBT_ACTIVATE:
      if GetParent(WParam) = 0 then
        PostMessage(GlobalData^.AppWnd, WMMyPost, 4, WParam);
  end;
  Result := CallNextHookEx(GlobalData^.SysHook, Code, WParam, LParam);
end;


procedure ManageHook(ASet: boolean; AWnd: HWND); export; stdcall;
begin
  if ASet then begin
    GlobalData^.SysHook := SetWindowsHookEx(WH_CBT, @CbtFunc, HInstance, 0);
    GlobalData^.AppWnd := AWnd;
    GlobalData^.WndMsg := RegisterWindowMessage('WM_MYPOST');

    if (GlobalData^.SysHook = 0) then
      DoLog('Hook: Unable to initialize hook');
  end
  else begin
    UnhookWindowsHookEx(GlobalData^.SysHook);
    GlobalData^.SysHook := 0;
  end;
end;


procedure OpenGlobalData;
begin
  MMFHandle :=
    CreateFileMapping(
      INVALID_HANDLE_VALUE, nil, PAGE_READWRITE, 0,
      SizeOf(TGlobalDLLData), MMF_NAME);

  if (MMFHandle = 0) then
    Exit;

  GlobalData :=
    MapViewOfFile(
      MMFHandle, FILE_MAP_ALL_ACCESS, 0, 0, SizeOf(TGlobalDLLData));
  if (GlobalData = nil) then begin
    CloseHandle(MMFHandle);
    Exit;
  end;
end;


procedure CloseGlobalData;
begin
  UnmapViewOfFile(GlobalData);
  CloseHandle(MMFHandle);
end;


procedure DLLEntryPoint(dwReason: DWORD); stdcall;
begin
  case dwReason of
    DLL_PROCESS_ATTACH: OpenGlobalData;
    DLL_PROCESS_DETACH: CloseGlobalData;
  end;
end;


{$R *.res}

exports
  ManageHook;

begin
  DLLProc:= @DLLEntryPoint;
  DLLEntryPoint(DLL_PROCESS_ATTACH);
end.