Как сделать всплывающее по правой кнопке меню?

Option Explicit
'Это должно быть в модуле
Public Const ComBarName = "MyBestBar"
Public ComBar As CommandBar, But(10) As CommandBarButton
Public Pop As CommandBarPopup

'Это должно быть в модуле
'Это для удобства формирования меню
Sub AddToBar(НомерКнопки As Integer, Название As String, Иконка As Integer, _
         ПослеЧерты As Boolean, ИмяМакроса As String)
    'Создает на панели ComBar кнопку с указанными свойствами
    Set But(НомерКнопки) = ComBar.Controls.Add(msoControlButton, 1)
    But(НомерКнопки).Caption = Название
    But(НомерКнопки).FaceId = Иконка
    But(НомерКнопки).BeginGroup = ПослеЧерты
    But(НомерКнопки).OnAction = ИмяМакроса
    But(НомерКнопки).Style = msoButtonIconAndCaption
    But(НомерКнопки).Enabled = True
End Sub

'Это должно быть в модуле
'Это пример процедуры, которая будет запускаться из контекстного меню
Private Sub Analis()
    Set ComBar = Application.CommandBars(ComBarName)
   
    Select Case CommandBars.ActionControl.Index
        Case 1 '
            MsgBox "1"
        Case 2 '
            MsgBox "2"
        Case 3 '
            MsgBox "3"
        Case 4 '
            MsgBox "4"
   
    End Select
    ComBar.Delete
End Sub

'Это должно быть в модуле листа
Private Sub Worksheet_BeforeRightClick(ByVal Target As Excel.Range, Cancel As Boolean)

    Cancel = True

    On Error Resume Next
    Application.CommandBars(ComBarName).Delete
    On Error GoTo 0

    Set ComBar = Application.CommandBars.Add(ComBarName, msoBarPopup, False, True)

    Call AddToBar(1, "Быстрее!", 481, False, "Analis")
    Call AddToBar(2, "Выше!", 482, False, "Analis")
    Call AddToBar(3, "Сильнее!", 483, False, "Analis")
    Call AddToBar(4, "Выход", 484, True, "Analis")

    ComBar.ShowPopup

End Sub

'А это все пример работы с подменю в контекстном меню и кнопками вкл/выкл
'Должно быть в модуле листа
Private Sub Worksheet_BeforeRightClick(ByVal Target As Excel.Range, Cancel As Boolean)
Dim NewBut As CommandBarButton, i As Integer

    Cancel = True
   
    On Error Resume Next
    Application.CommandBars("MyBestBar").Delete
    On Error GoTo 0
    Set ComBar = Application.CommandBars.Add("MyBestBar", msoBarPopup, False, True)

    Call AddToBar(1, "Сегодня воскресенье", 1, False, "Analis")
    Call AddToBar(2, "Взять пивка...", 59, False, "GetBeer")

    If WeekDay(Date, vbMonday) = vbSunday Then
        But(1).State = msoButtonDown
     Else
        But(1).State = msoButtonUp
     End If

    Set Pop = ComBar.Controls.Add(msoControlPopup, 1)
    Pop.Caption = "Сорта пива"
    Pop.BeginGroup = True
    Pop.Enabled = True
   
    i = 1
    While ThisWorkbook.Worksheets("Марки пива").Cells(i, 1).Value <> ""
        Set NewBut = Pop.Controls.Add(msoControlButton, 1)
        NewBut.Caption = ThisWorkbook.Worksheets("Марки пива").Cells(i, 1).Value
        NewBut.FaceId = 1
        NewBut.Style = msoButtonIconAndCaption
        If i = ThisWorkbook.Worksheets("Марки пива").Range("A2").Value Then
            NewBut.State = msoButtonDown
         Else
            NewBut.State = msoButtonUp
         End If
        NewBut.OnAction = "GetBeer"
        i = i + 1
    Wend
   
    ComBar.ShowPopup

End Sub

Public Sub GetBeer()
   
    Application.StatusBar = "Идет поиск нужного пива..."
    Application.Cursor = xlWait
    Application.ScreenUpdating = False

    ThisWorkbook.Worksheets("Марки пива").Range("A2").Value = _
            CommandBars.ActionControl.Index
    Application.StatusBar = ThisWorkbook.Worksheets("Марки пива"). _
            Cells(CommandBars.ActionControl.Index, 1).Value
   
    CommandBars("MyBestBar").Delete
   
    Application.StatusBar = False
    Application.Cursor = xlDefault
    Application.ScreenUpdating = True

End Sub