Удаление комментариев из кода

Option Explicit
On Error Resume Next
Dim mesaga 'сообщение
Dim res 'значение, возвращаемое функцией
'проверяем аргументы
If WScript.Arguments.Count = 0 Then'если нет аргументов
    mesaga = InputBox("Пожалуйста, введите имя файла", "Удаление комментариев","")
    If mesaga <> "" Then
        res = RemComm(mesaga)
    Else: WScript.Quit
    End If 
Else: res = RemComm(WScript.Arguments(0))  
End If
ResChk(res) 'вызываем процедуру проверки
'проверка на ошибки
Sub ResChk(res)
    If res = True Then
        MsgBox "Удаление комментариев завершено",vbInformation
    Else: MsgBox "В процессе удаления произошла ошибка",vbExclamation
    End If
End Sub
Function RemComm(fName)
    Dim replPatrn 'щаблон для замены комментов для RexExp
    Dim codeFileName 'имя файла с кодом для удаления комментов
    Dim codeFilePath 'полный путь к файлу с кодом - должен быть в том же каталоге
    Dim codeFilePathNew 'полное имя нового файла (с префиксом)
    Dim codeFile 'файл с кодом
    Dim codeFileNew 'новый файл
    Dim i 'счетчик
    Dim strArr() 'массив для файла с кодом
    Dim wshShell 'оболочка
    Dim fso 'файловая система
    Dim regEx ' переменная для RegExp
    Const newNamePref = "New-" 'префикс нового файла
    replPatrn = "'[^" & Chr(34) & "]*$|\t" 'собираем шаблон - комменты или символы табуляции
    codeFileName = fName
    Set wshShell = CreateObject("WScript.Shell")
    Set fso = CreateObject("Scripting.FileSystemObject")
    codeFilePath = wshShell.CurrentDirectory & "\" & codeFileName
    codeFilePathNew = wshShell.CurrentDirectory & "\" & newNamePref & codeFileName
    Set codeFile = fso.OpenTextFile(codeFilePath,1) 'открываем файл для чтения
        i = 0
        Do While codeFile.AtEndOfStream <> True 'читаем файл до конца
            ReDim Preserve strArr(i) 'перебиваем размерность массива       
            strArr(i) = Trim(codeFile.ReadLine) 'закидываем строки в массив, удаляем пробелы
            i = i + 1      
        Loop
        codeFile.Close
        Set codeFileNew = fso.CreateTextFile(codeFilePathNew,True) 'создаем файл, если существует - заменим      
        Set regEx = New RegExp 'создаем регулярное выражение.
        With regEx
            .Pattern = replPatrn 'определяем шаблон
            .Global = True   'устанавливаем глобальность применения
            .IgnoreCase = True  'устанавливаем нечувствительность к регистру
        End With       
        For i = 0 To UBound(strArr)
            strArr(i) = regEx.Replace(strArr(i),"") 'удаляем комменты
            If strArr(i) <> vbNullString Then codeFileNew.WriteLine strArr(i) 'пишем в файл, пропускаем пустые строки      
        Next
        codeFileNew.Close
    Set regEx = Nothing
    Set codeFileNew = Nothing
    Set codeFile = Nothing
    Set fso = Nothing  
    Set wshShell = Nothing
    If err = 0 Then
        RemComm = True
    Else: RemComm = False
    End If
End Function

wmiServices.ExecQuery("ASSOCIATORS OF {Win32_DiskDrive.DeviceID='" _
        & DevID & "'} WHERE AssocClass = Win32_DiskDriveToDiskPartition")

strReplPatrn = "'[^" & Chr(34) & "]*$|\t|\brem\b.*$|^\s+|\s+$"