Как получить коллекцию найденного из myRange.Find.Execute?

Sub ShowFind()
  frm_Find.Show vbModeless
End Sub

Option Explicit

Private Sub cbo_ResultFind_DropButtonClick()
Dim str_Split$()
'получить номер страницы
str_Split = Split(cbo_ResultFind.Value, Space(1))
'переход на другую страницу
Selection.GoTo wdGoToPage, wdGoToAbsolute, Val(str_Split(1))

End Sub

Private Sub chk_MatchCase_Change()
  'reset color Black
  ResetColorBlack
 
End Sub

Private Sub chk_WordSymbol_Change()

If chk_WordSymbol.Value Then
  chk_WordSymbol.Caption = "Поиск слова"
  txt_Find.MaxLength = 25
  txt_Find.Text = ""
Else
  chk_WordSymbol.Caption = "Поиск символа"
  txt_Find.MaxLength = 1
  txt_Find.Text = ""
End If

'reset color Black
ResetColorBlack

End Sub

Private Sub cmd_Start_Click()

If txt_Find.TextLength = 0 Then Exit Sub
RemovingItemsComboBox

'отключить экран (во время выполнения макроса)
Application.ScreenUpdating = False

Dim int_SearchResultOnPage%
Dim DocumentPages%()
Dim rng_Range As Range
Dim int_MemPageStart%

int_MemPageStart = 1

Set rng_Range = ActiveDocument.Range

ReDim DocumentPages(rng_Range.Information(wdActiveEndPageNumber), 0)

With rng_Range.Find
  .Text = txt_Find.Text                   'Что искать
  .MatchCase = chk_MatchCase              'Учитывать регистр
  .MatchWholeWord = chk_WordSymbol.Value  'Words/Characters
    Do While .Execute
      DoEvents
     
      If rng_Range.Information(wdActiveEndPageNumber) = int_MemPageStart Then
        'подщет совпадений на стронице
        int_SearchResultOnPage = int_SearchResultOnPage + 1
      Else
        'переход на другую страницу
        int_MemPageStart = rng_Range.Information(wdActiveEndPageNumber)
        int_SearchResultOnPage = 1
      End If
      'запись в массив совпадений на странице
      DocumentPages(rng_Range.Information(wdActiveEndPageNumber), 0) = int_SearchResultOnPage
    Loop
End With

'проверка
If int_SearchResultOnPage = 0 Then Exit Sub

fra_ResultFind.Enabled = True

Dim var_SetSearchColorSelect
Set rng_Range = ActiveDocument.Range

'reset color Black
For Each var_SetSearchColorSelect In rng_Range.Characters
  If var_SetSearchColorSelect.Font.ColorIndex = wdRed Then
    var_SetSearchColorSelect.Font.ColorIndex = wdBlack
  End If
Next

'выбор Words/Characters
If chk_WordSymbol.Value Then
  'поиск слов
  For Each var_SetSearchColorSelect In rng_Range.Words
    If RTrim(var_SetSearchColorSelect.Text) = txt_Find.Text Then
      var_SetSearchColorSelect.Font.ColorIndex = wdRed
    End If
  Next
Else
  'поиск Characters
  For Each var_SetSearchColorSelect In rng_Range.Characters
    If var_SetSearchColorSelect.Text = txt_Find.Text Then
      var_SetSearchColorSelect.Font.ColorIndex = wdRed
    End If
  Next
End If

'удалить объест
Set rng_Range = Nothing

'настройка ComboBox
With cbo_ResultFind
  .ColumnCount = UBound(DocumentPages)
  .ColumnWidths = "45;20;80"
  .ColumnHeads = False
  .RowSource = ""
End With

Dim int_CountPageFind%

'заполнить ComboBox
For int_SearchResultOnPage = 1 To UBound(DocumentPages)
  'не показывать страницы, где нет "Совпадений"
  If DocumentPages(int_SearchResultOnPage, 0) <> 0 Then
    cbo_ResultFind.AddItem "Страница" & Str(int_SearchResultOnPage)
    cbo_ResultFind.List(int_CountPageFind, 1) = Str(int_SearchResultOnPage)
    cbo_ResultFind.List(int_CountPageFind, 2) = "Совпадений " & DocumentPages(int_SearchResultOnPage, 0)
    int_CountPageFind = int_CountPageFind + 1
  End If
 
Next

cbo_ResultFind.ListIndex = 0

End Sub

Private Sub cmd_ResetSearchColorSelection_Click()
Dim rng_Range As Range
Dim var_ResetSearchColSel

'reset color Black
ResetColorBlack

RemovingItemsComboBox

'удалить объест
Set rng_Range = Nothing

End Sub

Private Sub RemovingItemsComboBox()
  'Removing Items ComboBox
  Do While cbo_ResultFind.ListCount > 0
    cbo_ResultFind.RemoveItem (0)
  Loop
  cbo_ResultFind.Text = ""
  fra_ResultFind.Enabled = False
 
End Sub

Private Sub ResetColorBlack()

Dim rng_Range As Range
Dim var_SetSearchColorSelect
Set rng_Range = ActiveDocument.Range

'reset color Black
For Each var_SetSearchColorSelect In rng_Range.Characters
  If var_SetSearchColorSelect.Font.ColorIndex = wdRed Then
    var_SetSearchColorSelect.Font.ColorIndex = wdBlack
  End If
Next

'удалить объест
Set rng_Range = Nothing

End Sub